VBScript初心者入門講座

VBScript初心者入門講座 http://vbscript.pgtop.net/ VBScriptのメリット、プログラミングの基本から、初心者向けに詳しく解説します。たぶん日本一簡単なプログラミング無料講座です。 ja http://vbscript.pgtop.net/article/451099773.html VBScriptのFor Next文で繰り返し処理を行ってみましょう。 VBScriptにもFor Next文が用意されているので、繰り返し処理(ループ処理)ができます。これまでのサンプルプログラムのようなお金の計算は、Excelなどの表計算ソフトでもできます。プログラミングが効果を発揮するのは、繰り返しや、条件分岐の時です。こんな条件の計算をしたい時のことをイメージしてみましょう。・1万回繰り返す計算・偶数の時だけ、加算する計算一見難しそうですが、実はプログラミングで制御構文を使えば、簡単に実現できます。例えば、VBScriptで繰り返し処理を.. For Next文で繰り返し処理 VBScript 2017-06-22T13:27:28+09:00 VBScriptにもFor Next文が用意されているので、繰り返し処理(ループ処理)ができます。

これまでのサンプルプログラムのようなお金の計算は、
Excelなどの表計算ソフトでもできます。

プログラミングが効果を発揮するのは、繰り返しや、条件分岐の時です。

こんな条件の計算をしたい時のことをイメージしてみましょう。
・1万回繰り返す計算
・偶数の時だけ、加算する計算

一見難しそうですが、実はプログラミングで制御構文を使えば、簡単に実現できます。

例えば、VBScriptで繰り返し処理を行いたい時の制御構文はいくつかあります。

その中で、指定した回数だけ処理を繰り返したい場合は、
よくFor Next文が使われます。

とりあえず今回は一番簡単な1～10の数字を足すプログラムを書いてみます。

それでは早速、試してみましょう。

【1】以下のようにプログラミングします。

ファイル名　sample025.vbs

Option Explicit

Dim ans, i, sum

For i = 1 To 10
sum = sum + i
Next

ans = "合計：" & sum

MsgBox ans, , "答え"

【2】準備ができたら、vbsファイルをダブルクリックして実行します。

【3】すると、以下のような計算結果になるはずです。

中身はとても簡単なプログラムですよね。

【プログラムの解説】
For Next文の書式は以下のようになっています。

For カウンタ用変数 = 初期値 To 最終値 [Step 加算する数]

この間に繰り返す処理を書く

Next文

カウンタ用変数には、よく i が使われます。

サンプルプログラムの
For i = 1 To 10
は変数iが1から10になるまでという意味です。

[Step 加算する数]は省略可能で、その場合は1ずつ加算されます。

つまり1,2,3・・・10と増えていくわけです。

変数sumにどんどん値が加算されていきます。

変数ansは答えをメッセージボックスに表示するためのものです。

ps:
このような計算は、数学では公式があるので、暗算でも出すことができます。

でもプログラミングが出来れば、
公式を知らなくてもコンピューターの力技で答えが出せるわけですｗ

ちなみにStepはマイナスで減らすことも出来ます。

また、For Next文の中にFor Next文があるような入れ子にして使う場合は、
変数にj,kも使われます。

あまり階層が深くなるようだと、
プログラムが複雑になるので、別の書き方が良いでしょう。

またExitステートメントを使えば、繰り返し処理を途中で抜け出すことも可能です。

]]> http://vbscript.pgtop.net/article/439320453.html VBScriptのFormatCurrency関数で通貨形式にしてみましょう。 VBScriptにはFormatCurrency関数が用意されているので、数値を通貨形式に変換して表示することができます。しかもFormatCurrency関数の引数には、小数点以下の桁数も指定できるので、とても便利です。金額の計算部分のプログラムもシンプルになります。それでは早速、試してみましょう。【1】以下のようにプログラミングします。前回作成した「sample024.vbs」をコピーして、ファイル名を変更し、書き換えてもかまいません。ファイル名　sample024-1... FormatCurrency関数 VBScript 2016-06-23T16:09:53+09:00 VBScriptにはFormatCurrency関数が用意されているので、数値を通貨形式に変換して表示することができます。

しかもFormatCurrency関数の引数には、
小数点以下の桁数も指定できるので、とても便利です。

金額の計算部分のプログラムもシンプルになります。

それでは早速、試してみましょう。

【1】以下のようにプログラミングします。

前回作成した「sample024.vbs」をコピーして、
ファイル名を変更し、書き換えてもかまいません。

ファイル名　sample024-1.vbs

Option Explicit

Dim ans
Dim y, m, d, h, min, s

y = InputBox("年収を入力してください。(円)", "入力")

m = y / 12
d = y / 365
h = d / 24
min = h / 60
s = min / 60

ans = "あなたの収入換算" & vbCr _
    & "年：" & FormatCurrency(y) & vbCr _
    & "月：" & FormatCurrency(m) & vbCr _
    & "日：" & FormatCurrency(d) & vbCr _
    & "時：" &FormatCurrency(h,1) & vbCr _
    & "分：" & FormatCurrency(min,2) & vbCr _
    & "秒：" & FormatCurrency(s,3)

MsgBox ans, , "答え"

【2】準備ができたら、vbsファイルをダブルクリックして実行します。

年収の金額を入力してみてください。
以下の図は年収5百万円の場合です。

【3】すると、以下のような計算結果になるはずです。

通貨形式なので、数値の前に\(エンマーク)が付いています。

また3桁ごとに「,」(カンマ)で区切られているので、
一目で金額がいくらなのか、分かりやすくなりました。

そして時間給からは、小数点以下も表示しています。

前のsample024.vbsの結果と2つ並べて表示すると、違いが分かりやすいです。

秒の部分で小数点以下第3位に違いがありますが、
これは使っている関数や計算によって、「丸め誤差」があるためです。

【プログラムの解説】
FormatCurrency関数を使うため、小数点以下の桁数を考えなくて良いので、
計算部分のプログラムがとてもシンプルになりました。
m = y / 12
d = y / 365
h = d / 24
min = h / 60
s = min / 60

sample024.vbsと比較するとよくわかりますが、
前の計算の値を次の計算で使えるので、式自体がシンプルです。

FormatCurrency関数の最初の引数は、書式を変換する式(または値)です。

2番目の引数が、小数点以下の桁数を指定する部分ですが、省略も可能です。

2番目以降の引数を省略している場合
FormatCurrency(y)
FormatCurrency(m)
FormatCurrency(d)

2番目の引数で、それぞれ小数点以下1位～3位まで指定している場合
FormatCurrency(h,1)
FormatCurrency(min,2)
FormatCurrency(s,3)

この部分で桁数を指定できるので、上記の計算部分がシンプルになっているわけです。

FormatCurrency関数には、他にも引数がありますが、省略できるので書いていません。

ps:
上記の計算式の部分でもFormatCurrency関数は使えますが、
かえって書き方が複雑になるので、今回の例のようなプログラムにしました。

VBScriptには他にもいろんな関数が用意されているので、
何ができるのか知っておくと便利ですよ。

]]> http://vbscript.pgtop.net/article/421332170.html VBScriptで作る収入換算アプリの回答例と解説。 VBScriptで作る収入換算のアプリケーションソフトの課題はできましたか？それでは解答例です。【1】以下のようにプログラミングします。ファイル名　sample024.vbsOption ExplicitDim ansDim y, m, d, h, min, sy = InputBox("年収を入力してください。(円)", "入力")m = Round(y / 12)d = Round(y / 365)h = Round(d / 24 * 10) / 10min = Roun.. 収入換算アプリの回答例と解説 VBScript 2015-06-26T13:24:12+09:00 VBScriptで作る収入換算のアプリケーションソフトの課題はできましたか？

それでは解答例です。

【1】以下のようにプログラミングします。

ファイル名　sample024.vbs

Option Explicit

Dim ans
Dim y, m, d, h, min, s

y = InputBox("年収を入力してください。(円)", "入力")

m = Round(y / 12)
d = Round(y / 365)
h = Round(d / 24 * 10) / 10
min = Round(h / 60 * 100) / 100
s = Round(min/60 * 1000) / 1000

ans = "あなたの収入換算" & vbCr _
    & "年：" & y & "円" & vbCr _
    & "月：" & m & "円" & vbCr _
    & "日：" & d & "円" & vbCr _
    & "時：" & h & "円" & vbCr _
    & "分：" & min & "円" & vbCr _
    & "秒：" & s & "円"

MsgBox ans, , "答え"

【2】vbsファイルをダブルクリックして実行します。

図のように、例えば年収の金額に5百万円と入力する場合は、
5000000 と入力します。

＊数字は、全て半角で入力します。

【3】すると、以下のような計算結果になるはずです。

小数点以下の桁数が、ちゃんと表示されています。

時、分、秒の換算が思ったより低いのは、時給を24時間で計算しているからです。

つまり寝ている間も働いていることになっています。

一般的な平均労働時間の8時間で計算すると、それなりの時給になるはずです。

例えば、一日の平均労働時間が8時間の人は、
24時間 ÷ 8時間＝ 3　なので、
時、分、秒の換算を、それぞれ3倍すると、労働時間当たりの収入がわかります。

ただし、そうなると残業時間が考慮されなくなるので、
今回はわざと24時間で計算しました。

個々の状況に合わせて、倍率を変えると、現実に近くなるはずです。

または今後の改善点として、一日の平均労働時間を、
インプットボックスから入力できるようにして、
プログラムの中で計算に利用すれば、より実用的なアプリになるでしょう。

仮に年収100億円の人の収入換算は、こんな結果になります。

やっぱりお金持ちは凄いですねｗ

【プログラムの解説】
変数を宣言している部分です。
Dim ans
Dim y, m, d, h, min, s

ansは答え、
yは年、mは月、dは日、hは時、minは分、sは秒の金額を表します。
min(分)だけ変数名が長いのは、m(月)と区別するためです。

InputBoxを表示し、ユーザーに入力してもらい、変数に代入している部分です。
y = InputBox("年収を入力してください。(円)", "入力")

Round関数を使い、四捨五入してから、変数に代入している部分です。
m = Round(y / 12)
d = Round(y / 365)
h = Round(d / 24 * 10) / 10
min = Round(h / 60 * 100) / 100
s = Round(min/60 * 1000) / 1000

月収は年収を12か月で割ると出せます。

日収は、毎月の日数が変化するので、
年収を365日で割ることで計算しています。
(今回は、うるう年を考慮していません。)

四捨五入による丸め誤差を気にしなければ、
前の式の計算結果を、次の式で使えます。

Round関数は、小数点以下しか四捨五入ができません。

そこで、ちょっと工夫が必要です。

例えば、年収5百万円の人の場合、
時給換算では、計算機で計算すると、
570.77625　となります。

この時、そのままRound関数で四捨五入すると、
571　になります。

時給は小数点第1位まで表示したいので、そのままでは使えません。
そこで元の数字を10倍しておいて、
5707.7625　を四捨五入します。

すると5708になりますよね？

あとは元の桁に戻すため、10で割ります。
答えは、570.8円になるわけです。

分や秒でも仕組みは同じで、
掛けたり、割ったりする単位が変わるだけです。

残りのプログラムは、計算した値を文字列として組み立て、
変数に代入しておいて、
最後にメッセージボックスに答えを表示しているだけです。

ans = "あなたの収入換算" & vbCr _
"年：" & y & "円" & vbCr _
"月：" & m & "円" & vbCr _
"日：" & d & "円" & vbCr _
"時：" & h & "円" & vbCr _
"分：" & min & "円" & vbCr _
"秒：" & s & "円"

MsgBox ans, , "答え"

どうでしたか？

解答例を見なくても出来た、プログラムの書き方が違っても同じ結果が出せればOKです。

ステップ順に学習を進め、理解している人は、
ほとんど問題なくプログラミングできたと思います。

]]> http://vbscript.pgtop.net/article/411032390.html VBScriptで、収入換算アプリを作ってみましょう。 VBScriptで作るアプリケーションソフトの応用です。年収から、月、日、時、分、秒まで、時間別の収入を計算できるアプリを作ってみましょう。ビル・ゲイツのような世界的な大富豪、スポーツ選手、スーパースター、芸能人達が、1日、1分、1秒で、一体いくら稼ぐのか、たまに話題になることがありますよね？私も興味がありますｗそのような計算ができるアプリを作りたいわけです。「収入換算アプリ」というネーミングが適しているかわかりませんが、イメージは掴めますよね？こんなアプリが作れればOKです.. 収入換算アプリを作る VBScript 2014-12-21T16:20:12+09:00 VBScriptで作るアプリケーションソフトの応用です。

年収から、月、日、時、分、秒まで、時間別の収入を計算できるアプリを作ってみましょう。

ビル・ゲイツのような世界的な大富豪、スポーツ選手、スーパースター、芸能人達が、
1日、1分、1秒で、一体いくら稼ぐのか、たまに話題になることがありますよね？

私も興味がありますｗ

そのような計算ができるアプリを作りたいわけです。

「収入換算アプリ」というネーミングが適しているかわかりませんが、

イメージは掴めますよね？

こんなアプリが作れればOKです。

一見、難しそうですが、

これまでに学んだプログラムのちょっとした応用で、簡単にできます。

【プログラム作成のヒント】
・時間を表す変数は、それぞれ y, m, d, h, min, s とする。(mは月で、minは分)
・年収は円単位で、インプットボックスから入力する。
・1年は365日で計算する。(うるう年は考慮しない)
・時給は24時間で計算する。(平均労働時間は人それぞれ違うので)

・計算結果は、Round関数で四捨五入する。
・今回は四捨五入による丸め誤差は気にしない。

・月、日は1円まで表示。
・時は小数点第1位まで表示。
・分は小数点第2位まで表示。
・秒は小数点第3位まで表示。

まずは答えを見る前に、ご自身で考えてみてください。

そのほうがプログラミングの力が付き、応用範囲も広がりますから。

どうですか、出来ましたか？

プログラムの回答例は、次回の記事に掲載します。

お楽しみに！

ps:
これまでのステップでやったVBScriptのプログラムをちゃんと理解できていれば、

上記のヒントだけで作れるはずです。

もし何も思いつかない、イメージできない場合は、
VBScriptプログラミングの理解不足なので、
ステップを戻って復習したほうが、近道かも。

]]> http://vbscript.pgtop.net/article/322489759.html VBScriptで、Round関数の代わりに、IntやFixを使ってみましょう。 VBScriptには、さまざまな関数が用意されていることは、これまでにも説明してきました。Round関数のように、小数点以下の計算に使える関数は、他にもいくつかあります。Round()　小数点以下を四捨五入します。Int()　小数点以下を切り捨てます。Fix()　小数点以下を切り捨てます。今回は、Round関数の代わりに、IntやFixを使った場合に、計算結果がどう変わるか、試してみましょう。【1】ファイル名sample023.vbsをコピーして、sample023-1.vb.. Round関数とIntやFixとの違い VBScript 2013-02-14T22:31:38+09:00 VBScriptには、さまざまな関数が用意されていることは、これまでにも説明してきました。

Round関数のように、小数点以下の計算に使える関数は、他にもいくつかあります。

Round()　小数点以下を四捨五入します。
Int()　小数点以下を切り捨てます。
Fix()　小数点以下を切り捨てます。

今回は、Round関数の代わりに、IntやFixを使った場合に、計算結果がどう変わるか、試してみましょう。

【1】ファイル名sample023.vbsをコピーして、sample023-1.vbsとsample023-2.vbsを作ります。

【2】あとはRoundの部分を、それぞれIntやFixに書き換えるだけです。

【3】準備が出来たら、各プログラムを実行してみましょう。

左から、Round、Int、Fixの場合の結果です。

Roundは四捨五入です。

IntとFixは、同じく切り捨てです。

でも厳密に言うと、IntとFixでは、マイナスの値の場合、小数点以下の処理が、ちょっと異なります。

今回は、計算結果が同じになりましたが。

このように使う関数を何にするかで、計算結果が異なります。

したがって、得たい結果(目的)に合わせて、どの関数を使うか、考える必要があります。

関数を使いこなし、オリジナルのアプリケーションソフトを、いろいろ改良したり、カスタマイズできると、プログラミングが楽しいですよね。

]]> http://vbscript.pgtop.net/article/321877351.html VBScriptで作った割り勘アプリを改良してみましょう。 VBScriptのメリットは、プログラムを改良したり、カスタマイズすることが、簡単にできることです。そこで前回に作った、割り勘アプリを改良してみましょう。改良点・会計時の金額と、人数も表示する。・幹事が人数分集めた合計金額がわかるようにする。このような場合も、簡単にできます。【1】以下のようにプログラミングします。ファイル名　sample023.vbsOption ExplicitDim ans, m, pDim y1, y10, y100m = InputBox("金額を入.. 割り勘アプリを改良する VBScript 2013-02-11T21:11:51+09:00 VBScriptのメリットは、プログラムを改良したり、カスタマイズすることが、簡単にできることです。

そこで前回に作った、割り勘アプリを改良してみましょう。

改良点
・会計時の金額と、人数も表示する。
・幹事が人数分集めた合計金額がわかるようにする。

このような場合も、簡単にできます。

【1】以下のようにプログラミングします。

ファイル名　sample023.vbs

Option Explicit

Dim ans, m, p
Dim y1, y10, y100

m = InputBox("金額を入力してください。", "入力")
p = InputBox("人数を入力してください。", "入力")

y1 = Round(m / p)
y10 = Round(m / p / 10) * 10
y100 = Round(m / p / 100) * 100

ans = "金額：" & m & "円" & "　人数：" & p & "人" & vbCr _
    & "1円単位：" & y1 & "円 → " & (y1 * p) & "円" & vbCr _
    & "10円単位：" & y10 & "円 → " & (y10 * p) & "円" & vbCr _
    & "100円単位：" & y100 & "円 → " & (y100 * p) & "円"

MsgBox ans, , "答え"

【2】vbsファイルをダブルクリックして実行します。

図のように金額は10000、

人数は6を入力します。

＊数字は、全て半角で入力します。

【3】すると、以下のような計算結果になるはずです。

ちゃんと金額、人数が表示されています。
幹事が人数分集めた合計金額がわかるようになったので、便利ですね。

あと課題があるとすれば、金額が少ないと、精度がいまいちです。

例えば、金額は1000、人数は6を入力してみてください。

100円単位が雑で、多く集めてしまうことになります。

幹事さんは儲かりますが(笑)

まぁ、飲み会でお会計が1000円ということはないでしょうし、
金額が上がるほど、精度はよくなりますから、とりあえずOKとしましょう。

【プログラムの解説】
今回新たに加えた部分だけ説明します。

金額と人数を表示している部分です。
ans = "金額：" & m & "円" & "　人数：" & p & "人" & vbCr _
わざと全角のスペースで、文字の間を空けています。

人数分の合計金額を表示している部分です。
→ " & (y1 * p) & "円"
→ " & (y10 * p) & "円"
→ " & (y100 * p) & "円"

変数pには、人数が入っているので、掛け算をしているだけです。

どうですか？

このように、プログラミングが出来ると、オリジナルのアプリケーションソフトの改良やカスタマイズが、自由自在に出来るのが、プログラミングの楽しさです。

]]> http://vbscript.pgtop.net/article/321817006.html VBScriptで、割り勘アプリを作ってみましょう。 VBScriptで、ちょっと実用的なアプリケーションソフト(アプリ)を作ってみましょう。今回は、飲み会で便利な「割り勘アプリ」を作ることにします。実用的といっても、飲み会にパソコンを持っていく人はいないでしょうが(笑)、プログラミングの学習としては、適している課題だと思いますので。実はとても簡単に作れます。これまでに学んだプログラミング技術だけで、作ることができます。飲み会の最後で面倒なのが、割り勘ですよね。「どこまで細かく割り勘するか？」という問題があります。そこで、1円単.. 割り勘アプリを作る VBScript 2013-02-11T10:32:24+09:00 VBScriptで、ちょっと実用的なアプリケーションソフト(アプリ)を作ってみましょう。

今回は、飲み会で便利な「割り勘アプリ」を作ることにします。

実用的といっても、飲み会にパソコンを持っていく人はいないでしょうが(笑)、
プログラミングの学習としては、適している課題だと思いますので。

実はとても簡単に作れます。

これまでに学んだプログラミング技術だけで、作ることができます。

飲み会の最後で面倒なのが、割り勘ですよね。

「どこまで細かく割り勘するか？」という問題があります。

そこで、1円単位、10円単位、100円単位の全てに対応できるアプリを作りましょう。

1000円単位は、暗算で簡単に計算できるので、除きます。

【1】以下のようにプログラミングします。

ファイル名　sample022.vbs

Option Explicit

Dim ans, m, p
Dim y1, y10, y100

m = InputBox("金額を入力してください。", "入力")
p = InputBox("人数を入力してください。", "入力")

y1 = Round(m / p)
y10 = Round(m / p / 10) * 10
y100 = Round(m / p / 100) * 100

ans = "1円単位：" & y1 & "円" & vbCr _
& "10円単位：" & y10 & "円" & vbCr _
& "100円単位：" & y100 & "円"

MsgBox ans, , "答え"

【2】vbsファイルをダブルクリックして実行します。

図のように金額は10000、

人数は6を入力します。

＊数字は、全て半角で入力します。

【3】すると、以下のような計算結果になるはずです。

ちゃんと1円単位、10円単位、100円単位の全てで、計算されています。

ただし、プログラムにエラー処理を書いていないので、
・数字以外の文字や記号
・全角の数字
・「キャンセル」ボタンを押す
などをすると、エラーメッセージが出るので、注意してください。

【プログラムの解説】
変数を宣言している部分です。
Dim ans, m, p
Dim y1, y10, y100

ansは答え、mは金額、pは人数、
y1は1円単位、y10は10円単位、y100は100円単位を表します。

1y、10y、100yのほうが分かりやすい気がしますが、
変数名の最初の文字には、数字が使えないためです。

InputBoxを表示し、ユーザーに入力してもらい、変数に代入している部分です。
m = InputBox("金額を入力してください。", "入力")
p = InputBox("人数を入力してください。", "入力")

Round関数を使い、四捨五入してから、変数に代入している部分です。
y1 = Round(m / p)
y10 = Round(m / p / 10) * 10
y100 = Round(m / p / 100) * 100

ここで重要なポイントですが、
Round関数は、小数点以下しか四捨五入ができません。

そこで、ちょっと工夫が必要になるわけです。

1円単位の場合は、小数点以下を四捨五入すればよいので、そのまま使えます。
y1 = Round(m / p)

10円単位の場合は、あえて10で割ることで、
1円の単位を小数点にしてから、四捨五入し、10を掛けて、元の桁に戻しています。
y10 = Round(m / p / 10) * 10

100円単位の場合も、同じような考え方です。割る桁が違うだけです。
y100 = Round(m / p / 100) * 100

このような方法は、プログラミングでは、よく使われています。
覚えておくと便利です。

変数ansに、あらかじめメッセージボックスに表示する文字列を、代入している部分です。
ans = "1円単位：" & y1 & "円" & vbCr _
& "10円単位：" & y10 & "円" & vbCr _
& "100円単位：" & y100 & "円"

これは復習になりますが、
「vbCr」は、MsgBox内での改行です。
「 _」(半角スペースとアンダーバー)は、プログラム内での改行です。

あとは答えを表示しているだけです。
MsgBox ans, , "答え"

どうでしたか？
技術的には、これまでのプログラミングで学んだことだけで、実用的なアプリが作れましたね。

少しだけ、計算に工夫が必要でしたが。

]]> http://vbscript.pgtop.net/article/319411336.html VBScriptでInputBoxを使い、値を入力できるようにしましょう。 VBScriptでは、InputBox(インプットボックス)という、文字入力ダイアログボックスが使えます。InputBoxを使えば、ユーザーがプログラムに値を渡すことができます。例えば、sample019.vbsでは、プログラムに変数の値を、直接書き込んでいました。a = 10b = 3c = 5これはこれで、プログラム中に値を残せるメリットはあります。でも、値が変わる度に、プログラムを書き換えるのは、面倒です。そこで今回は、InputBoxを使い、プログラムに直接、値を渡せ.. InputBoxで値を入力する VBScript 2013-02-07T14:24:05+09:00 VBScriptでは、InputBox(インプットボックス)という、文字入力ダイアログボックスが使えます。

InputBoxを使えば、ユーザーがプログラムに値を渡すことができます。

例えば、sample019.vbsでは、プログラムに変数の値を、直接書き込んでいました。
a = 10
b = 3
c = 5

これはこれで、プログラム中に値を残せるメリットはあります。

でも、値が変わる度に、プログラムを書き換えるのは、面倒です。

そこで今回は、InputBoxを使い、プログラムに直接、値を渡せるように改良してみましょう。

簡単ですよ。

【1】以下のようにプログラミングします。

ファイル名　sample021.vbs

Option Explicit

Dim ans, a, b, c

a = InputBox("aの値を入力してください。", "入力")
b = InputBox("bの値を入力してください。", "入力")
c = InputBox("小数点何位まで求めますか？", "入力")

ans = Round(a / b, c)

MsgBox ans, , "答え"

【2】vbsファイルをダブルクリックして実行します。

図のようにaの値は10、bの値は3、cの値は5を入力します。
全て半角で入力します。

すると、sample019.vbsと同じ計算結果になるはずです。

ただし、プログラムにエラー処理を書いていないので、
・数字以外の文字や記号
・全角の数字
・「キャンセル」ボタンを押す
などをすると、エラーメッセージが出るので、注意してください。

【3】次の場合でも試してみてください。
aの値は10、bの値は6、cの値は5

sample020.vbsと同じ計算結果になるはずです。

このように、InputBoxを使うと、一つのプログラムで、いろんな計算結果を出すことができます。

【プログラムの解説】
InputBoxの書式は、以下の通りです。
[変数] = InputBox("メッセージ", [タイトル])

受け取る側の[変数]や、2つ目の引数である、[タイトル]は、省略可能です。

InputBoxは、ユーザーが入力した値を返すので、受け取る変数を左辺に準備しておきます。
a = InputBox("aの値を入力してください。", "入力")
b = InputBox("bの値を入力してください。", "入力")
c = InputBox("小数点何位まで求めますか？", "入力")

メッセージは、プログラムの実行時に、InputBoxが表示された時、
ユーザーが何を入力するのか、わかりやすい言葉を書いておきます。

あとはこれまでのプログラムと同じで、

計算して、
ans = Round(a / b, c)

表示しているだけです。
MsgBox ans, , "答え"

余裕のある人は、InputBoxに入力する数値を変え、いろいろ試してみてください。

ちょっとシステム開発っぽくなってきましたね。

]]> http://vbscript.pgtop.net/article/319378048.html VBScriptで、計算に使えるさまざまな関数一覧です。 VBScriptには、前回のRound関数以外にも、計算(数値演算)に使えるさまざまな関数が、あらかじめ用意されています。計算に使えるさまざまな関数一覧Round()　小数点以下を四捨五入します。Int()　小数点以下を切り捨てます。Fix()　小数点以下を切り捨てます。＊IntとFixでは、引数にマイナスの値を指定した時に、結果が異なります。Sgn()　符号を調べます。Abs()　絶対値を求めます。Log()　自然対数を求めます。Exp()　べき乗を求めます。Sqr()　平.. 計算に使える関数一覧 VBScript 2013-02-07T13:50:03+09:00 VBScriptには、前回のRound関数以外にも、計算(数値演算)に使えるさまざまな関数が、あらかじめ用意されています。

計算に使えるさまざまな関数一覧
Round()　小数点以下を四捨五入します。
Int()　小数点以下を切り捨てます。
Fix()　小数点以下を切り捨てます。
＊IntとFixでは、引数にマイナスの値を指定した時に、結果が異なります。

Sgn()　符号を調べます。
Abs()　絶対値を求めます。
Log()　自然対数を求めます。
Exp()　べき乗を求めます。
Sqr()　平方根を求めます。
Sin()　サインを求めます。
Cos()　コサインを求めます。
Tan()　タンジェントを求めます。
Atn()　アークタンジェントを求めます。
Rnd()　乱数を返します。
Oct()　8進数に変換します。
Hex()　16進数に変換します。

VBScriptの関数について、もっと知りたくなった方は、以下のような書籍が参考になります。

VBScriptの機能について、辞書的に調べることができるので、
便利なポケットリファレンスです。

関数の使い方、引数の種類などについて、詳しく書かれています。

]]> http://vbscript.pgtop.net/article/319129058.html VBScriptで、関数を使った計算式に挑戦してみましょう。 VBScriptには、計算に使えるさまざまな関数が用意されています。今回は、関数を使い、もうちょっと複雑な計算式に挑戦してみましょう。関数が使えると、便利です。プログラムが簡単になります。例えば「Round」は、小数点以下を四捨五入してくれる関数です。どの位置で四捨五入するか、引数で指定もできます。早速、試してみましょう。【1】以下のようにプログラミングします。ファイル名　sample019.vbsOption ExplicitDim ans, a, b, ca = 10b .. 関数を使った計算式 VBScript 2013-02-06T13:56:48+09:00 VBScriptには、計算に使えるさまざまな関数が用意されています。

今回は、関数を使い、もうちょっと複雑な計算式に挑戦してみましょう。

関数が使えると、便利です。
プログラムが簡単になります。

例えば「Round」は、小数点以下を四捨五入してくれる関数です。

どの位置で四捨五入するか、引数で指定もできます。

早速、試してみましょう。

【1】以下のようにプログラミングします。

ファイル名　sample019.vbs

Option Explicit

Dim ans, a, b, c

a = 10
b = 3
c = 5

ans = Round(a / b, c)

MsgBox ans, , "答え"

【2】vbsファイルをダブルクリックして実行します。

この計算式の小数点以下は、ずっと3が続きます。
そこで四捨五入され、第5位までが求められています。

ちゃんと切り捨てられています。

でもこの計算だけだと、本当に四捨五入されているか、わかり難いですよね。

小数点が、5以上の場合がわからないからです。

【3】次のプログラムも試してみてください。

ファイル名　sample020.vbs

Option Explicit

Dim ans, a, b, c

a = 10
b = 6
c = 5

ans = Round(a / b, c)

MsgBox ans, , "答え"

この計算式の小数点以下は、ずっと6が続きます。
四捨五入され、第5位が繰り上がっています。

これでちゃんと四捨五入されているのが、確認できました。

【プログラムの解説】
まとめて変数を宣言しています。
Dim ans, a, b, c

変数に値を代入しています。
a = 10
b = 3
c = 5

実際に計算して、答えを代入している部分です。
ans = Round(a / b, c)

Roundの書式は、以下の通りです。
Round(数値, [小数点の位置])

したがって、変数を実際の数値に置き換えると、
ans = Round(10 / 3, 5)
となります。

これは、10÷3 の答えを、小数点第5位まで求めるという意味になります。

2つ目の引数である、[小数点の位置]は、省略可能です。
省略した場合は、小数点以下を四捨五入して、整数部分だけになります。

あとはメッセージボックスに表示するだけです。
MsgBox ans, , "答え"

余裕のある人は、変数に代入する数値を変え、いろいろ試してみてください。

]]> http://vbscript.pgtop.net/article/318599440.html VBScript 一つのプログラムで、複数の計算ができる方法とは？ VBScriptで、オリジナルの計算機を作ってみました。でも、計算式や値が変わる度に、何度もソースファイルを作るのは面倒ですよね？そこで今回は、ちょっとしたコツを紹介します。次のような計算用のプログラムを、一つだけ用意します。ファイル名　calc.vbsOption ExplicitDim ansans = 1 + 2 + 3 + 4 + 5'ans = (1 + 2) / 3 * (4 - 5)MsgBox ans, , "答え"このプログラムを実行すると、ans = 1 .. 複数の計算を試すには？ VBScript 2013-02-04T09:48:12+09:00 VBScriptで、オリジナルの計算機を作ってみました。

でも、計算式や値が変わる度に、何度もソースファイルを作るのは面倒ですよね？

そこで今回は、ちょっとしたコツを紹介します。

次のような計算用のプログラムを、一つだけ用意します。

ファイル名　calc.vbs

Option Explicit

Dim ans

ans = 1 + 2 + 3 + 4 + 5
'ans = (1 + 2) / 3 * (4 - 5)

MsgBox ans, , "答え"

このプログラムを実行すると、
ans = 1 + 2 + 3 + 4 + 5
の答えが表示されるはずです。

二つ目の計算式は、「'」(シングルクォーテーション)で、コメントになっているからです。
'ans = (1 + 2) / 3 * (4 - 5)

コメントにした行は、プログラムの実行時には、無視されるので、結果に影響しないことは、前にも説明しましたね。

別の計算式を試したい時には、「'」を付けたり、外したりします。

このように、コメントは、注釈だけではなく、プログラム実行の有無にも使えます。

コメントを使うことで、一つのファイルに、たくさんの計算式を書いておけます。

便利なテクニックなので、覚えておいてください。

]]> http://vbscript.pgtop.net/article/318597522.html VBScriptで、簡単な計算機を作ってみましょう。 VBScriptで、オリジナルの計算機を作ってみましょう。プログラムで計算ができると、VBScriptの用途が、一気に広がります。メリットとしては、プログラムの中に、計算式が残せるので、修正がしやすいこと。応用すると、電卓よりも、もうちょっと複雑な計算ができることなどです。とても簡単なので、早速試してみましょう。【1】以下のようにプログラミングします。ファイル名　sample017.vbsOption ExplicitDim ansans = 1 + 2 + 3 + 4 + .. 簡単な計算機を作る VBScript 2013-02-04T09:24:23+09:00 VBScriptで、オリジナルの計算機を作ってみましょう。

プログラムで計算ができると、VBScriptの用途が、一気に広がります。

メリットとしては、プログラムの中に、計算式が残せるので、修正がしやすいこと。

応用すると、電卓よりも、もうちょっと複雑な計算ができることなどです。

とても簡単なので、早速試してみましょう。

【1】以下のようにプログラミングします。

ファイル名　sample017.vbs

Option Explicit

Dim ans

ans = 1 + 2 + 3 + 4 + 5

MsgBox ans, , "答え"

【2】vbsファイルをダブルクリックして実行します。

ちゃんと計算結果が表示されましたね。
答えも合っています。

【3】次は四則演算を組み合わせた式を試してみましょう。

ファイル名　sample018.vbs

Option Explicit

Dim ans

ans = (1 + 2) / 3 * (4 - 5)

MsgBox ans, , "答え"

【4】vbsファイルをダブルクリックして実行します。

これも大丈夫です。
( )カッコの計算や、演算子の優先順位もバッチリです。

このように、ちょっと複雑な計算になると、電卓では面倒だし、
式や数値が変わると、修正したり、何度も試すのは大変です。

VBScriptでは、プログラムの中に計算式が書けるので、便利ですよね。

これだけでも、VBScriptでプログラミングする価値があります。

ここまで来ると、プログラムでコンピューターを操作する感覚が掴めるのではないでしょうか？

それがプログラミングの楽しさです。

【プログラムの解説】
あらかじめansという変数を宣言しておいて、
Dim ans

計算結果を変数に代入し、
ans = 1 + 2 + 3 + 4 + 5
ans = (1 + 2) / 3 * (4 - 5)

メッセージボックスで表示しているだけです。(タイトル付き)
MsgBox ans, , "答え"

また、プログラミングでは、四則演算に使う記号(演算子)が、算数とはちょっと違います。
そこだけは注意してください。

足し算や引き算は同じですが、

×(掛け算)は、*(アスタリスク)を使います。
÷(割り算)は、/(スラッシュ)を使います。

そして *、/ は、必ず半角で入力します。

]]> http://vbscript.pgtop.net/article/318502106.html VBScriptで、メッセージボックスに、タイトルを表示してみましょう。 VBScriptでは、メッセージボックス(MsgBox)に、タイトルを表示することができます。通常、メッセージボックスの書式は、以下の通りです。MsgBox(メッセージ[, ボタンの種類, [タイトル]])[ ](カッコ)は、省略可能な引数を表しています。つまりメッセージ以外は、省略可能です。だから今までは、MsgBox(str) という使い方ができたわけです。また、引数が複数ある場合は、「,」(カンマ)で区切る決まりになっています。したがって今回は、以下のような書式を使いま.. MsgBoxにタイトルを表示する VBScript 2013-02-03T23:02:57+09:00 VBScriptでは、メッセージボックス(MsgBox)に、タイトルを表示することができます。

通常、メッセージボックスの書式は、以下の通りです。
MsgBox(メッセージ[, ボタンの種類, [タイトル]])

[ ](カッコ)は、省略可能な引数を表しています。
つまりメッセージ以外は、省略可能です。

だから今までは、MsgBox(str) という使い方ができたわけです。

また、引数が複数ある場合は、「,」(カンマ)で区切る決まりになっています。

したがって今回は、以下のような書式を使います。
MsgBox(メッセージ, , [タイトル])

ポイントは、省略した引数も、カンマは残しておく必要があることです。

そして大事なポイントが、もう一つあります。

実は、上記の書式のままMsgBoxを使うと、実行時にエラーが出ます。

原因は、MsgBoxが値を返すためです。

そのため( )を使う場合は、プログラムの書き方が、少し異なります。
これについては、後で説明します。

一番簡単な解決策は、( )を外すことです。

ということで、最終的な書式は、以下の通りです。
MsgBox メッセージ, , [タイトル]

【1】以下のようにプログラミングします。

ファイル名　sample014.vbs

Option Explicit

Dim str

str = "日付：" & Date & vbCr & "時刻：" & Time

MsgBox str, , "時計"

＊「,」は半角ですので、入力する時は、注意してください。

【2】vbsファイルをダブルクリックして実行します。

どうですか？
MsgBoxにタイトルが表示されますよね。

ついでに、( )を付けた場合のプログラムも書いておきます。

ファイル名　sample015.vbs

Option Explicit

Dim str, res

str = "日付：" & Date & vbCr & "時刻：" & Time

res = MsgBox(str, , "時計")

あらかじめ res という変数を用意しておきます。
(変数名は何でもかまいません)

そして、MsgBoxが返す値(戻り値)を、変数resで受け取ります。
ここで受け取るとは、代入するという意味。

たったこれだけです。

でも前者のほうが、プログラムがシンプルですよね。

【プログラムの解説】
変数は、複数まとめて宣言できます。カンマで区切ります。
Dim str, res

分けて書いても同じです。
Dim str
Dim res

余裕がある人は、試してみてください。

ファイル名　sample016.vbs

Option Explicit

Dim str
Dim res

str = "日付：" & Date & vbCr & "時刻：" & Time

res = MsgBox(str, , "時計")

]]> http://vbscript.pgtop.net/article/318269716.html VBScriptで、プログラムの中にコメントを書くには？ VBScriptでも、プログラム(ソースコード)の中にコメントを書くことができます。プログラミング言語で言うコメントとは、注釈のことです。コメントは、プログラムについての補足的な説明や、メモと考えてください。プログラムは、時間が経つと、書いた本人でさえわからなくなることがあります。第三者から見れば、なおさらです。そこで通常は、プログラマーがプログラムを書く時に、コメントを書き込みます。コメントがあると、プログラムの保守管理がしやすくなるメリットがあります。【1】以下のように、.. VBScriptにコメントを書く VBScript 2013-02-03T13:12:05+09:00 VBScriptでも、プログラム(ソースコード)の中にコメントを書くことができます。

プログラミング言語で言うコメントとは、注釈のことです。

コメントは、プログラムについての補足的な説明や、メモと考えてください。

プログラムは、時間が経つと、書いた本人でさえわからなくなることがあります。

第三者から見れば、なおさらです。

そこで通常は、プログラマーがプログラムを書く時に、コメントを書き込みます。

コメントがあると、プログラムの保守管理がしやすくなるメリットがあります。

【1】以下のように、コメントを含めてプログラミングします。

ファイル名　sample013.vbs

'変数を明示的に宣言
Option Explicit

'変数を宣言
Dim str

'変数に値を代入
str = "日付：" & Date & vbCr & "時刻：" & Time

'メッセージボックスで変数を表示
MsgBox(str)

＊「'」は半角ですので、入力する時は、注意してください。

【2】vbsファイルをダブルクリックして実行します。

これまで通り、ちゃんと動きますね。

コメントがあるおかげで、プログラムの意味が、わかりやすくなったと思います。

【プログラムの解説】
「'」(シングルクォーテーション)の後から、行末までがコメントになります。

「'」の代わりに「Rem」を使うこともできますが、「'」のほうが一般的です。

プログラムの実行時には、コメントは無視されるので、動作に影響はありません。

長いコメントも書けますが、普通は短く、わかりやすく書きます。

]]> http://vbscript.pgtop.net/article/318268381.html VBScriptで、変数とOption Explicitの役割について。 VBScriptで変数を宣言しないで使うと、どうなるでしょうか？試しに、以下のプログラムを書き、実行してみてください。ファイル名　sample011.vbsOption Explicitstr = "日付：" & Date & vbCr & "時刻：" & TimeMsgBox(str)このようにメッセージボックスで、エラーが表示されるはずです。Option Explicitを書いているのに、変数を宣言しないで使っているからです。このエラーメッ.. Option Explicitの役割 VBScript 2013-02-03T12:55:12+09:00 VBScriptで変数を宣言しないで使うと、どうなるでしょうか？

試しに、以下のプログラムを書き、実行してみてください。

ファイル名　sample011.vbs

Option Explicit

str = "日付：" & Date & vbCr & "時刻：" & Time

MsgBox(str)

このようにメッセージボックスで、エラーが表示されるはずです。

Option Explicitを書いているのに、変数を宣言しないで使っているからです。

このエラーメッセージは、出てくれたほうが助かる、ありがたいものです。

つまり、Option Explicitを使うことで、変数の宣言忘れを防げるのです。

さらにOption Explicitも無い場合はどうでしょうか？

ファイル名　sample011.vbs

str = "日付：" & Date & vbCr & "時刻：" & Time

MsgBox(str)

この場合は、普通に表示されるはずです。

意外でしたか？

Option Explicitが無いので、変数の宣言をしなくても、使えるからです。

実はVBScriptは、変数を宣言しても、しなくても使えます。

しかしプログラミング的には、明示的に変数を宣言して使ったほうが良い、とされています。

予想外のエラーを防ぐためです。

そこで今後は、明示的に変数を宣言する方法で、プログラミングの学習を進めることにします。

]]>